/* *****************************************************************
 *    File Name : 27HC291.D   (Gang is not supported !!!:PROM)
 *    Pin num   : 24-pin	 (A0..A10	D0..D7)
 *    Memory size : 16K (7FF) 
 *    Last Modify Date : 91. 3. 7 
 *
 *    Vpp	: 12.5	   Vcc : 6.0    Dur : 1ms  (Fast Algo.)
 *    Device 	: MICROCHIP   	27HC191/291	
 * ***************************************************************** */
declaration
   dataunit : byte;
   functions
      Program
      Read
      Verify
      Blank_Check
      Data_Compare
      Auto
   ;
   Manufacturers
      MICROCHIP
   ;
   Devices
      D27HC191
      D27HC291
   ;
   chips = A7, A6, A5, A4, A3, A2,  A1,  A0, 	  D0,  D1, D2, GND,
	   D3, D4, D5, D6, D7, CS3, CS2, CS1:Vpp, A10, A9, A8, Vcc;
   $v2 = Vpp;
   $v3 = Vcc;
endd

/* -----------------------------------------------------------------------
 * Failf () ---> Fail address setting
 * ----------------------------------------------------------------------- */
int Failf (hwhb, hwlb, lwhb, lwlb, tmp)
int hwhb, hwlb, lwhb, lwlb, tmp;
{
int high, low;

   high = (hwhb << 8) | hwlb;
   low  = (lwhb << 8) | lwlb;

   @Fail high, low, tmp;
}
/* ----------------------------------------------------------------------
 * init () ---> Initial processing
 * ---------------------------------------------------------------------- */
int     init (vol2, vol3)
voltage vol2, vol3;
{
  @Vout  2, vol2;
  @Vout  3, vol3;
  @Out GND,  @G;
  @Delay 10, @ms;

  @Out D[0..7]  , @Z;
  @Out A[0..7]  , @W;
  @Out A[8..10] , @W; 
  @Out Vcc	, @W;
  @Out CS1      , @W;
  @Out CS2	, @W;       
  @Out CS3      , @W;
  @Out Vpp	, @W;
  
  @Out Vcc      , @H;
  @Out Vpp	, @H;  
  @Out CS1      , @H;       /* Chip enable  is High */
  @Out CS2      , @H;    
  @Out CS3      , @H;       /* Out  enable  is High */

  @Out Vcc     , @O;
  @Delay 100   , @us;
}
/* ----------------------------------------------------------------------
 * InitProcess () ---> Initial Buffer | Voltage source
 * ---------------------------------------------------------------------- */
int InitProcess ()
{
   if (FUNCTION != Program) init ( 5.0 , 5.0 );
   else			    init (12.5 , 6.0 );
}
/* ----------------------------------------------------------------------
 * read () ---> read processing
 * ---------------------------------------------------------------------- */
int read (row)
int	row;
{
int  hwhb, hwlb, lwhb, lwlb;
int  sll, ell, slh, elh;
int  tmp, tmp2;

   lwlb = lwhb = hwhb = hwlb = 0;
   sll = ell = slh = elh = tmp = tmp2 = 0;
   
   @Set B_HADDR, B_LADDR;
   @Inc	__B_START__;
   
   if (FUNCTION == Read ) 
   {
      @Display 26, row, "Reading...";
      @CheckSumON;
   }
   else if (FUNCTION == Verify)		@Display 26, row, "Verifying...";
   else if (FUNCTION == Blank_Check)	@Display 26, row, "Blank Checking...";
   else 			        @Display 26, row, "Data Comparing...";

   for ( hwhb=0 /* S_HWHB */ ; hwhb<=0 /* E_HWHB */; hwhb++ )
   {
      @Display 64, 9, hwhb;
      for ( hwlb=0 /* S_HWLB */; hwlb<=0 /* E_HWLB */; hwlb++ )
      {
         @Display 66, 9, hwlb;
         if (hwlb == S_HWLB) slh = S_LWHB;
         else                slh = 0;
         if (hwlb == E_HWLB) elh = E_LWHB;
         else                elh = 0xFF;
         
	 for ( lwhb=slh; lwhb<= elh; lwhb++)
         {
            @Display 68, 9, lwhb;
	    @Out A [8..10], lwhb;   /* Output High word address */
	    
	    if (lwhb == S_LWHB) sll = S_LWLB;
            else                sll = 0;
            if (lwhb == E_LWHB) ell = E_LWLB;
            else                ell = 0xFF;

	    for ( lwlb=sll; lwlb<=ell; lwlb++)
	    {
	       @Out A [0..7], lwlb;    /* Low  byte address output */
 	       @Out CS1     , @L;
	       @In  D [0..7], tmp;
	       @Out CS1	    , @H;
	       	       
	       if (FUNCTION == Read)          @Load tmp;
	       else if (FUNCTION == Blank_Check)
	       {
		  if (tmp != 0xFF /* Blank Char  */)
		     Failf (hwhb, hwlb, lwhb, lwlb, tmp);
	       }
	       else if (FUNCTION == Verify)
               {
                  @Store tmp2;
                  if (tmp != tmp2) Failf (hwhb, hwlb, lwhb, lwlb, tmp);
	       }
               else if (FUNCTION == Data_Compare)
               {
               	    @Store	tmp2;
               	    @Compare	tmp, tmp2;
               }
	       if (FUNCTION != Blank_Check)	@Inc SPLIT;
            }
	 }
      }
   }
   if 	   (FUNCTION == Read)		@Display 26, row, "Read OK!   ";
   else if (FUNCTION == Verify)		@Display 26, row, "Verification OK!";
   else if (FUNCTION == Blank_Check)	@Display 26, row, "Blank Check OK!  ";
   else 			        @Display 26, row, "Data Comparison OK!";
}
/* -----------------------------------------------------------------------
 * program() ---> Control main
 * ----------------------------------------------------------------------- */
int program (row, kind)
int	row, kind;
{
int  hwhb, hwlb, lwhb, lwlb;
int  sll, ell, slh, elh;
int  tmp , tmp2, failcnt;

   @Set  B_HADDR, B_LADDR;
   @Inc  __B_START__;
   
   failcnt = lwlb = lwhb = hwhb = hwlb = 0;
   sll = ell = slh = elh = tmp = tmp2 = 0;
	
   @Display 26, row, "Programming...";   
   
   @Out	Vpp      , @O;
   
   for ( hwhb=S_HWHB; hwhb<=E_HWHB; hwhb++ )
   {
       @Display 64, 9, hwhb;
       for ( hwlb=S_HWLB; hwlb<=E_HWLB; hwlb++ )
       {
           @Display 66, 9, hwlb;
           if (hwlb == S_HWLB) slh = S_LWHB;
           else                slh = 0;
           if (hwlb == E_HWLB) elh = E_LWHB;
           else                elh = 0xFF;
           
           for ( lwhb=slh; lwhb<=elh; lwhb++)
	   {
               @Display 68, 9, lwhb;
	       @Out A [8..10], lwhb;   /* Output High word address */
	       
	       if (lwhb == S_LWHB) sll = S_LWLB;
               else                sll = 0;
               if (lwhb == E_LWHB) ell = E_LWLB;
               else                ell = 0xFF;

	       for ( lwlb=sll; lwlb<=ell; lwlb++)
	       {
		  @Store tmp;
		  
		  if (tmp == 0xFF)
		  {
		      @Inc  SPLIT;
		      continue;
		  }
		  
 		  @Out D [0..7], @W;		  
	          @Out A [0..7], lwlb;
	          @Out D [0..7], tmp;
	          @Out CS3     , @L;
	          @Delay 1     , @ms;
	          @Out CS3     , @H;
	          
	          /* ------ One Byte Verify -------- */
		  @Out D [0..7], @Z;
		  @Out CS2     , @L;
	          @In  D [0..7], tmp2;
	
		  @Out CS2     , @H;
		  
		  if (tmp != tmp2)
                  {
		     if (failcnt > 25) Failf (hwhb, hwlb, lwhb, lwlb, tmp2);
                     else 
                     {
                        ++ failcnt;
                     	lwlb--;
                     }
                  }
                  else 
                  {
                      failcnt = 0;
		      @Inc SPLIT;
 		  }
               }
	   }
       }
   }
   @Display 26, row, "Program OK!   ";
   FUNCTION = Verify;
   @Vout 2, 5.0;
   @Vout 3, 5.0;
   if (kind == 0) row = 7;
   else		  row = 8;
   read (row);		/*  Verify  */
}   
/* ---------------------------------------------------------------------
 * main () ---> Control main
 * -------------------------------------------------------------------- */
int main ()
{
   InitProcess();                            

   if ( FUNCTION == Auto )
   {
       FUNCTION = Blank_Check;
       read (6);
       
       FUNCTION = Program;
       program (7, 1);
   }
   if ( FUNCTION == Program ) 	program(6, 0);
   else 		   	read (6);
}
/* ---------------------------- End of program --------------------------- */