/* ****************************************************************************
 *    File Name 	: 28256.D  (Electrical Eraser PROM)
 *    Pin num		: 28-pin	(A0..A14	D0..D7)
 *    Memory Size      	: 256K (7FFF)
 *    Last Modify Date 	: 91. 3. 19 
 *
 *    Vcc	: 5.0		Erase : Vpp=12.0
 *    Device 	: 
 *      Dur=1 ms: MICROCHIP     28C256  
 *	Dur=3ms : ATMEL		28C256F	 28HC256F
 *		  MICROCHIP	28C256F
 *	Dur=10ms: ATMEL		28C256	 28HC256	28HC256L   
 *		  SAMSUNG	28C256(256K)	
 *		  NEC		*28C256
 *		  XICOR		28256	28C256	28C256B
 *		  SEEQ		28C256
 * ************************************************************************** */
declaration
   dataunit : byte;
   functions
      Program
      Read
      Verify
      Blank_Check
      Data_Compare
   ;
   Manufacturers
      MICROCHIP      	/*  1ms */   
      ATMEL		/*  10ms */
      SAMSUNG
      NEC
      XICOR
      SEEQ
   ;
   Devices
      D28256
      D28C256
      D28C256B
      D28C256F
      D28HC256
      D28HC256F
      D28HC256L
   ;      
   chips = A14, A12, A7, A6, A5, A4, A3,  A2, A1,  A0, D0, D1 , D2, GND,
	   D3 , D4 , D5, D6, D7, CE, A10, OE, A11, A9, A8, A13, WE, Vcc;
   $v2 = OE;	   
   $v3 = Vcc;
endd

/* -----------------------------------------------------------------------
 * Failf () ---> Fail address setting
 * ----------------------------------------------------------------------- */
int Failf (hwhb, hwlb, lwhb, lwlb, tmp)
int hwhb, hwlb, lwhb, lwlb, tmp;
{
int high, low;

   high = (hwhb << 8) | hwlb;
   low  = (lwhb << 8) | lwlb;

   @Fail high, low, tmp;
}
/* -----------------------------------------------------------------------
 * init () ---> Initial processing
 * ----------------------------------------------------------------------- */
int     init ( vol3 )
voltage  vol3;
{
   @Vout 3	 , vol3;     /* Voltage Source #3 */
   @Out GND      , @G;       /* Ground output */
   @Delay 10	 , @ms;

   @Out D [0..7] , @W;       /* ------------------------ */
   @Out A [0..7] , @W;       /*                          */
   @Out A [8..14], @W;       /*   Initial Direction      */
   @Out CE       , @W;       /*         Of               */
   @Out WE	 , @W;	     /*        Port		 */
   @Out OE       , @W;       /* ------------------------ */
   @Out Vcc	 , @W;
   @Out __GANG__[0..3], @W;

   @Out CE       , @H;       /* Chip enable  is High */
   @Out OE       , @H;       /* Out  enable  is High */
   @Out WE	 , @H;
   @Out Vcc	 , @L;   
   @Out __GANG__[0..3], @H;
   
   @Out Vcc      , @O;       /* Vcc Enable */
   @Delay 100	 , @Ms;
}
/* -----------------------------------------------------------------------
 * InitProcess () ---> Initial Buffer | Voltage source
 * ----------------------------------------------------------------------- */
int InitProcess ()
{
   init ( 5.0 );
}
/* -----------------------------------------------------------------------
 * read () ---> read processing
 * ----------------------------------------------------------------------- */
int read (row)
int	row;
{
int  hwhb, hwlb, lwhb, lwlb;
int  sll, ell, slh, elh;
int  tmp, tmp2;

   lwlb = lwhb = hwhb = hwlb = 0;
   sll  = ell  = slh  = elh  = tmp = tmp2 = 0;
   
   @Set B_HADDR, B_LADDR;
   @Out D [0..7], @Z;	/* Data Input  */
   
   if ( FUNCTION == Read ) 
   {
      @Display 26, row, "Reading...";
      @CheckSumON;
   }
   else if (FUNCTION == Verify)		@Display 26, row, "Verifying...";
   else if (FUNCTION == Blank_Check)	@Display 26, row, "Blank Checking...";
   else 			        @Display 26, row, "Data Comparing...";   

   for ( hwhb=0 /* S_HWHB */ ; hwhb<=0 /* E_HWHB */; hwhb++ )
   {
      @Display 64, 9, hwhb;
      for ( hwlb=0 /* S_HWLB */; hwlb<=0 /* E_HWLB */; hwlb++ )
      {
         @Display 66, 9, hwlb;
         
         if (hwlb == S_HWLB) slh = S_LWHB;
         else                slh = 0;
         if (hwlb == E_HWLB) elh = E_LWHB;
         else                elh = 0xFF;
         
	 for ( lwhb=slh; lwhb<= elh; lwhb++)
         {
            @Display 68, 9, lwhb;
	    @Out A [8..14], lwhb;   /* Output High word address */
	    
	    if (lwhb == S_LWHB) sll = S_LWLB;
            else                sll = 0;
            if (lwhb == E_LWHB) ell = E_LWLB;
            else                ell = 0xFF;

	    for ( lwlb=sll; lwlb<=ell; lwlb++)
	    {
	       @Out A [0..7], lwlb;    /* Low  byte address output */
	       
	       if (GANG == 0)	@Out CE            , @L;
	       else		@Out __GANG__[GANG], @L;
	       
	       @Out OE      , @L;
	       @In  D [0..7], tmp;
	       
	       if (GANG == 0)	@Out CE	    	   , @H;
	       else		@Out __GANG__[GANG], @H;
	       
	       @Out OE	    , @H;

	       if (FUNCTION == Read)          @Load tmp;
	       else if (FUNCTION == Blank_Check)
	       {
		  if (tmp != 0xFF /* Blank Char  */)
		     Failf (hwhb, hwlb, lwhb, lwlb, tmp);
	       }
	       else if (FUNCTION == Verify)
               {
                  @Store tmp2;
                  if (tmp != tmp2) Failf (hwhb, hwlb, lwhb, lwlb, tmp);
	       }
	       else if (FUNCTION == Data_Compare) 
	       {
		    @Store	tmp2;
		    @Compare	tmp, tmp2;
	       }
	       if (FUNCTION != Blank_Check)	@Inc SPLIT;
            }
	 }
      }
   }
   if 	   (FUNCTION == Read)		@Display 26, row, "Read OK!   ";
   else if (FUNCTION == Verify)		@Display 26, row, "Verification OK!";
   else if (FUNCTION == Blank_Check)	@Display 26, row, "Blank Check OK!  ";
   else 			        @Display 26, row, "Data Comparison OK!";
}
/* -----------------------------------------------------------------------
 * program() ---> Control main
 * ----------------------------------------------------------------------- */
int program ()
{
int  hwhb, hwlb, lwhb, lwlb;
int  sll, ell, slh, elh, Dur;
int  tmp , tmp2, count;

   @Set  B_HADDR, B_LADDR;
   @Inc  __B_START__;
   
   lwlb = lwhb = hwhb = hwlb = count = 0;
   sll = ell = slh = elh = Dur = tmp = tmp2 = 0;
	
   if 	   (MFG == MICROCHIP)		
   {
   	if (DEVICE == D28C256)	Dur = 1;
   	else			Dur = 3;
   }
   else if (MFG == ATMEL)
   {
   	if (DEVICE == D28C256F || DEVICE == D28HC256F)	Dur = 3;
   	else						Dur = 10;
   }
   else 						Dur = 10; 
   
   @Display 26, 6, "Programming...";   
   
   @Out OE        , @L; 
   
   for ( hwhb=0 /* S_HWHB */; hwhb<=0 /* E_HWHB */; hwhb++)
   {
       @Display 64, 9, hwhb;
       for ( hwlb=0 /* S_HWLB */; hwlb<=0 /* E_HWLB */; hwlb++ )
       {
           @Display 66, 9, hwlb;
           
           if (hwlb == S_HWLB) slh = S_LWHB;
           else                slh = 0;
           if (hwlb == E_HWLB) elh = E_LWHB;
           else                elh = 0xFF;
           
           for ( lwhb=slh; lwhb<=elh; lwhb++)
           {
               @Display 68, 9, lwhb;
               @Out A [8..14], lwhb;   /* Output High word address */
               
               if (lwhb == S_LWHB) sll = S_LWLB;
               else                sll = 0;
               if (lwhb == E_LWHB) ell = E_LWLB;
               else                ell = 0xFF;

               for ( lwlb=sll; lwlb<=ell; lwlb++)
               {
                  @Store tmp;
                  
                  @Out A [0..7], lwlb;
                  @Out D [0..7], tmp;                  
                  @Out OE      , @H;
                  if (GANG == 0)        @Out CE            , @L;
                  else                  @Out __GANG__[GANG], @L;
                  @Out WE      , @L;
                  
                  if (GANG == 0)        @Out CE            , @H;
                  else                  @Out __GANG__[GANG], @H;
                  @Out WE      , @H;
                  @Out OE      , @L;
                  
                  /* -------- Verify --------- *
                  @Out D [0..7], @Z;
                  if (GANG == 0)        @Out CE            , @L;
                  else                  @Out __GANG__[GANG], @L;
                  @Out OE      , @L;
                  @In  D [0..7], tmp2;
                  @Out OE      , @H;
                  
                  if (tmp != tmp2)      Failf (hwhb, hwlb, lwhb, lwlb, tmp2);       
                  
                  if (GANG == 0)        @Out CE            , @H;
                  else                  @Out __GANG__[GANG], @H;
                  
                  @Out D [0..7], @W;
*/                
		  count ++;  
                  if (count == 64)	 
                  {
                      count=0;
                      @Delay Dur , @Ms;
                  }
		  
                  @Inc SPLIT;             
               }	
           }
       }
   }   
   @Display 26, 6, "Program OK!   ";
   FUNCTION = Verify;
   read (7);		/*  Verify  */
}

/* -----------------------------------------------------------------------
 * main () ---> Control main
 * ----------------------------------------------------------------------- */
int main ()
{
   InitProcess();

   if ( FUNCTION == Program ) 	program();
   else if ( FUNCTION == Read )
   {
   	if 	(GANG >= 1 && __B_START__ == 0);
   	else if (GANG == 3 && __B_START__ == 1);
   	else read (6);
   }    
   else 			read (6);
}
/* ---------------------------- End of program --------------------------- */ 