/* ***************************************************************************
 *    File Name : 4MIBYTE.D
 *    Pin num   : 32-pin	(A0..A18      D0..D7)
 *    Size	: 4M (7FFFF)
 *    Last Modify Date : 91. 3. 7 
 * ---------------------------------------------------------------------------
 *    Vpp=12.75		Vcc=6.25	Dur=100us
 * --------------------------------------------------------------------------- 
 *    Device 	: INTEL         27C040
 *	          WSI	 	27C040L
 *		  TOSHIBA	TC574000D (Dur=50)	
 * ************************************************************************* */
declaration
   dataunit : byte;
   functions
      Program
      Read
      Verify
      Blank_Check
      Data_Compare
      Auto      
   ;
   Manufacturers
      INTEL
      WSI
      TOSHIBA
   ;
   Devices
      D27C040
      D27C040L
      DTC574000D
   ;
   chips = Vpp, A16, A15, A12, A7, A6, A5, A4, A3, A2, A1, A0, D0, D1, D2,  GND,
	   D3 , D4 , D5 , D6 , D7, CE, A10,OE, A11,A9, A8, A13,A14,A17,A18, Vcc;
   $v2 = Vpp;
   $v3 = Vcc;
endd

/* -----------------------------------------------------------------------
 * Failf () ---> Fail address setting
 * ----------------------------------------------------------------------- */
int Failf (hwhb, hwlb, lwhb, lwlb, tmp)
int hwhb, hwlb, lwhb, lwlb, tmp;
{
int high, low;

   high = (hwhb << 8) | hwlb;
   low  = (lwhb << 8) | lwlb;

   @Fail high, low, tmp;
}
/* -----------------------------------------------------------------------
 * init () ---> Initial processing
 * ----------------------------------------------------------------------- */
int     init (vol2, vol3)
voltage vol2, vol3;
{
   @Vout 2, vol2;            /* Voltage Source #2 */
   @Vout 3, vol3;            /* Voltage Source #3 */
   @Out GND      , @G;       /* Ground output */
   @Delay 10	 , @ms;

   @Out D [0..7] , @W;       /* ------------------------ */
   @Out A [0..7] , @W;       /*                          */
   @Out A [8..15], @W;       /*   Initial Direction      */
   @Out A [16..18],@W;
   @Out CE       , @W;       /*         Of               */
   @Out OE       , @W;       /* ------------------------ */
   @Out __GANG__[0..3], @W;

   @Out CE       , @H;       /* Chip enable  is High */
   @Out OE       , @H;       /* Out  enable  is High */
   @Out __GANG__[0..3], @H;

   @Out Vcc	 , @O;       /* Vcc Enable */
   @Out Vpp	 , @O;       /* Vpp Enable */
   @Delay 100	 , @us;
}
/* -----------------------------------------------------------------------
 * InitProcess () ---> Initial Buffer | Voltage source
 * ----------------------------------------------------------------------- */
int InitProcess ()
{
   if (FUNCTION != Program) init ( 5.0 , 5.0 );
   else                     init (12.75, 6.25);
}
/* -----------------------------------------------------------------------
 * read () ---> read processing
 * ----------------------------------------------------------------------- */
int read (row)
int	row;
{
int  hwhb, hwlb, lwhb, lwlb;
int  sll, ell, slh, elh, shl, ehl;
int  tmp, tmp2;

   lwlb = lwhb = hwhb = hwlb = 0;
   sll = ell = slh = elh = shl = ehl = tmp= tmp2 = 0;
   
   @Set B_HADDR, B_LADDR;
   @Out D [0..7], @Z;	/* Data Input  */
   
   if (FUNCTION == Read ) 
   {
      @Display 26, row, "Reading...";
      @CheckSumON;
   }
   else if (FUNCTION == Verify)		@Display 26, row, "Verifying...";
   else if (FUNCTION == Blank_Check)	@Display 26, row, "Blank Checking...";
   else 			        @Display 26, row, "Data Comparing...";   

   for ( hwhb=0 /* S_HWHB */ ; hwhb<=0 /* E_HWHB */; hwhb++ )
   {
      @Display 64, 9, hwhb;
      if (hwhb == S_HWHB) shl = S_HWLB;
      else                shl = 0;
      if (hwhb == E_HWHB) ehl = E_HWLB;
      else                ehl = 0xFF;
      
      for ( hwlb=shl; hwlb<=ehl; hwlb++ )
      {
	 @Display 66, 9, hwlb;
	 @Out A [16..18], hwlb;   /* Output High word address */
	 
	 if (hwlb == S_HWLB) slh = S_LWHB;
         else                slh = 0;
         if (hwlb == E_HWLB) elh = E_LWHB;
         else                elh = 0xFF;

	 for ( lwhb=slh; lwhb<=elh; lwhb++)
         {
	    @Display 68, 9, lwhb;
	    @Out A [8..15], lwhb;   /* Output High word address */
	    
	    if (lwhb == S_LWHB) sll = S_LWLB;
            else                sll = 0;
            if (lwhb == E_LWHB) ell = E_LWLB;
            else                ell = 0xFF;


	    for ( lwlb=sll; lwlb<=ell; lwlb++)
	    {
	       @Out A [0..7], lwlb;    /* Low  byte address output */
	       
	       if (GANG == 0)	@Out CE      	   , @L;
	       else		@Out __GANG__[GANG], @L;
	       
	       @Out OE      , @L;
	       @In  D [0..7], tmp;
	       
	       if (GANG == 0)	@Out CE	    	   , @H;
	       else		@Out __GANG__[GANG], @H;
	       
	       @Out OE      , @H;

	       if      (FUNCTION == Read)          @Load tmp;
	       else if (FUNCTION == Verify)
	       {
		   @Store tmp2;
		   if (tmp != tmp2)  Failf (hwhb, hwlb, lwhb, lwlb, tmp);
	       }
	       else if (FUNCTION == Blank_Check)   /* Blank_Char */
	       {
		    if (tmp != 0xFF)	Failf(hwhb, hwlb, lwhb, lwlb, tmp);
	       }
	       else if (FUNCTION == Data_Compare) 
	       {
	       	    @Store	tmp2;
	       	    @Compare	tmp, tmp2;
	       }		       
	       if ( FUNCTION != Blank_Check )	@Inc SPLIT;
            }
	 }
      }
   }
   if 	   (FUNCTION == Read)		@Display 26, row, "Read OK!   ";
   else if (FUNCTION == Verify)		@Display 26, row, "Verification OK!";
   else if (FUNCTION == Blank_Check)	@Display 26, row, "Blank Check OK!  ";
   else 			        @Display 26, row, "Data Comparison OK!";
}
/* -----------------------------------------------------------------------
 * program() ---> Control main
 * ----------------------------------------------------------------------- */
int	program (row, kind)
int	row, kind;
{
int  hwhb, hwlb, lwhb, lwlb;
int  sll, ell, slh, elh, shl, ehl;
int  tmp , tmp2, failcnt, Dur;

   Dur = failcnt = lwlb = lwhb = hwhb = hwlb = 0;
   sll = ell = slh = elh = shl = ehl = tmp= tmp2=0;
   
   @Set  B_HADDR, B_LADDR;
   @Inc  __B_START__;
   
   if (DEVICE == DTC574000D)	Dur = 50;
   else				Dur = 100;
   
   @Display 26, row, "Programming...";   
   
   for ( hwhb=0 /* S_HWHB */; hwhb<=0 /* E_HWHB */; hwhb++ )
   {
      @Display 64, 9, hwhb;
      if (hwhb == S_HWHB) shl = S_HWLB;
      else                shl = 0;
      if (hwhb == E_HWHB) ehl = E_HWLB;
      else                ehl = 0xFF;
       for ( hwlb=shl ; hwlb<=ehl; hwlb++ )
       {
	   @Display 66, 9, hwlb;
           @Out A [16..18], hwlb;   /* Output High word address */
           
           if (hwlb == S_HWLB) slh = S_LWHB;
           else                slh = 0;
           if (hwlb == E_HWLB) elh = E_LWHB;
           else                elh = 0xFF;

	   for ( lwhb=slh; lwhb<=elh; lwhb++)
	   {
	       @Display 68, 9, lwhb;
	       @Out A [8..15], lwhb;   /* Output High word address */
	       
	       if (lwhb == S_LWHB) sll = S_LWLB;
               else                sll = 0;
               if (lwhb == E_LWHB) ell = E_LWLB;
               else                ell = 0xFF;

	       for ( lwlb=sll; lwlb<=ell; lwlb++)
	       {
		  @Store tmp;
		  
		  if (tmp == 0xFF)
		  {
		      @Inc	SPLIT;
		      continue;
		  }
		  
	          @Out A [0..7], lwlb;
		  @Out D [0..7], tmp;

		  if (GANG == 0)	@Out CE		   , @L;
		  else			@Out __GANG__[GANG], @L;
		  
		  @Delay Dur	, @us;
		  
		  if (GANG == 0)	@Out CE	   	   , @H;
		  else			@Out __GANG__[GANG], @H;
		  
		  /* -------- Verify ----------- */
	          @Out D [0..7], @Z;
		  @Out OE      , @L;

	          @In  D [0..7], tmp2;
		  @Out OE      , @H;

		  @Out D [0..7], @W;

		  if (tmp != tmp2)
                  {
		     if (failcnt > 25) Failf (hwhb, hwlb, lwhb, lwlb, tmp2);
		     else
		     {
			++ failcnt;
			lwlb--;
		     }
                  }
		  else
		  {
			failcnt = 0;
			@Inc SPLIT;
		  }
               }
	   }
       }
   }
   @Display 26, row, "Program OK!   ";
   if (kind == 0)	row = 7;
   else			row = 8;
   FUNCTION = Verify;
   @Vout 2	, 5.0;
   @Vout 3	, 5.0;
   read (row);		/*  Verify  */   
}

/* -----------------------------------------------------------------------
 * main () ---> Control main
 * ----------------------------------------------------------------------- */
int main ()
{
   InitProcess();

   if ( FUNCTION == Auto )
   {
	FUNCTION = Blank_Check;
	read (6);
	
	FUNCTION = Program;
	InitProcess ();
	program(7, 1);
   }
   else if ( FUNCTION == Program ) program(6, 0);
   else if ( FUNCTION == Read )
   {
   	if 	(GANG >= 1 && __B_START__ == 0);
   	else if (GANG == 3 && __B_START__ == 1);
   	else read (6);
   }    
   else 			   read (6);
}
/* ---------------------------- End of program --------------------------- */ 